Office365里新增的几个Excel函数

办公教程导读

收集整理了【Office365里新增的几个Excel函数】办公软件教程，小编现在分享给大家，供广大互联网技能从业者学习和参考。文章包含1258字，纯文字阅读大概需要2分钟。

办公教程内容图文

今天和大家一起来分享一下Office 365里新增的几个函数。

先来看这个：

多个条件的判断：

按分数来判断是不是合格，这个想必大家经常会遇到吧。使用IF函数判断，那公式必定是多个IF，眼花缭乱的：

=IF(D2>89,"优秀",IF(D2>79,"良好",IF(D2>69,"一般",IF(D2>59,"合格","不合格"))))

现在，只需这样：

=IFS(D2>89,"优秀",D2>79,"良好",D2>69,"一般",D2>59,"合格",1=1,"不合格")

只要一个IFS函数，参数直接就是一组一组的判断条件和相应要返回的结果。多条件判断，再也不用晕头转向了。

除此之外，还可以使用SWITCH函数对多个条件进行判断。

比如下面的这个公式：

=SWITCH(A1,1,"OK",15,"YES",18,"NO","")

如果A1等于1，返回结果"OK"。如果A1等于15，返回结果"YES"，如果A1等于18，返回结果"NO"，否则返回空文本""。

按条件计算最小值

这也是一个经常遇到的问题，就像下面这个图中，要计算班级为乙班，并且性别为女性的最低分数：

在之前，如果我们要计算符合某个条件的最小值，需要使用数组公式来实现。模式化的数组公式是这样的：

{=MIN(IF((B3:B12="乙班")*(D3:D12="女"),E3:E12))}

注意，这个可是数组公式，需要按Ctrl+Shift+回车来结束公式编辑的。

现在，只需这样：

=MINIFS(G3:G12,D3:D12,"乙班",F3:F12,"女")

公式的用法类似于SUMIFS函数，第一个参数是需要计算的数据区域，后面是成对的区域/条件。

如果要计算符合条件的最大值，只要把公式中的MINIFS换成MAXIFS就OK了。

下面这个问题，相信大家也遇到过，就是按条件提取名单。

比方说下图中，就是提取班组为“乙班”的所有人员名单，并且在姓名中间用逗号隔开。

在之前，解决这个问题必须要使用VBA代码完成，这对于大多数普通用户，门槛还是太高了。

现在，只要用下面这个数组公式，就OK了。

{=TEXTJOIN(",",TRUE,IF(D3:D12="乙班",E3:E12,""))}

其中第一个参数是指定的间隔符号，后面这个True，表示忽略空单元格，如果使用FALSE，就是表示包括空单元格。

要简化公式的话，这里的逻辑值也可以省略参数，只使用逗号占位：

{=TEXTJOIN(",",,IF(D3:D12="乙班",E3:E12,""))}

要连接各个单元格的内容，现在也变得如此简单。

只需要输入下面这个数组公式，就可以快速的将D3:F12单元格区域的内容连接到一起，并且使用顿号隔开。

{=CONCAT(D3:F12&"、")}

之前对于这种问题，大家会使用PHONETIC函数来连接。但是PHONETIC函数比较挑剔，对于公式返回的结果就无能为力了，而且不支持对内存数组进行连接。现在有了CONCAT函数，一切变得那么简单。