excel 合并工作表的方法，用VBA代码实现合并工作表

办公教程导读

收集整理了【excel 合并工作表的方法，用VBA代码实现合并工作表】办公软件教程，小编现在分享给大家，供广大互联网技能从业者学习和参考。文章包含1316字，纯文字阅读大概需要2分钟。

办公教程内容图文

　　一般的做法，通过“移动或复制”实现合并工作表。要高效，可以使用VBA代码来实现合并工作表。

　　合并工作表操作步骤：

　　新建一个excel文件，按ALT+F11，打开VBE编辑器，复制下面的代码，然后运行，选择文件夹下面的所有excel文件，执行合并工作表。

Sub 合并工作簿()
    Dim FilesToOpen, wb As Workbook, sht As Worksheet
    Dim x As Integer

    On Error GoTo ErrHandler
    Application.ScreenUpdating = False

    FilesToOpen = Application.GetOpenFilename _
      (FileFilter:="Microsoft Excel Files (*.xlsx), *.xlsx", _
      MultiSelect:=True, Title:="Files to Merge")

    If TypeName(FilesToOpen) = "Boolean" Then
        MsgBox "No Files were selected"
        GoTo ExitHandler
    End If

    x = 1
    While x <= UBound(FilesToOpen)
        If FilesToOpen(x) <> ThisWorkbook.FullName Then
            Set wb = Workbooks.Open(Filename:=FilesToOpen(x))
            For Each sht In wb.Sheets
                sht.Copy After:=ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count)
            Next
            wb.Close
        End If
        x = x + 1
    Wend

ExitHandler:
    Application.ScreenUpdating = True
    Exit Sub

ErrHandler:
    MsgBox Err.Description
    Resume ExitHandler
End Sub

　　说明：上面代码是合并xlsx文件，如果是合并excel2003的文件，需要将：FileFilter:="Microsoft Excel Files (*.xlsx), *.xlsx"，xlsx改为.xls。

办公教程总结

以上是为您收集整理的【excel 合并工作表的方法，用VBA代码实现合并工作表】办公软件教程的全部内容，希望文章能够帮你了解办公软件教程excel 合并工作表的方法，用VBA代码实现合并工作表。
如果觉得办公软件教程内容还不错，欢迎将网站推荐给好友。